SICP - Solution: Exercise 1.23

October 16, 2018

Exercise 1.23 #

The smallest-divisor procedure shown at the start of this section does lots of needless testing: After it checks to see if the number is divisible by 2 there is no point in checking to see if it is divisible by any larger even numbers. This suggests that the values used for test-divisor should not be 2, 3, 4, 5, 6, …, but rather 2, 3, 5, 7, 9, …. To implement this change, define a procedure next that returns 3 if its input is equal to 2 and otherwise returns its input plus 2. Modify the smallest-divisor procedure to use (next test-divisor) instead of (+ test-divisor 1). With timed-prime-test incorporating this modified version of smallest-divisor, run the test for each of the 12 primes found in Exercise 1.22. Since this modification halves the number of test steps, you should expect it to run about twice as fast. Is this expectation confirmed? If not, what is the observed ratio of the speeds of the two algorithms, and how do you explain the fact that it is different from 2?

Solution #

The goal of this exercise is to try an improvement in the prime check program and see if we understand correctly how it impacted performance. The improvement is easy enough to write.

(define (next n)
  (if (= n 2)
      3
      (+ 2 n)))

and update:

(define (find-divisor-improved n test-divisor)
  (cond ((> (square test-divisor) n)
         n)
        ((divides? test-divisor n)
         test-divisor)
        (else (find-divisor-improved
               n
               (next test-divisor)))))

Here too, the initial tests with only one run were very inconsistent from run to run. I decided to extend the program to run the computation for each prime 1000 times and measure the result.

DrRacket #

The raw data from DrRacket, using some variation of the code you can find here:

This data can be summarized by averaging the time for each of the three prime in the same range of size:

Looking at this table, we notice numbers ranging from 113,6% to 164,5%. Even if the data is noisy, it seems clear that this is below the expected 200%.

Chicken Scheme (compiled) #

In order to check the number, I compiled the program with Chicken Scheme on OS X and got these results:

That can be averaged and summarized by averaging the time for each of the three prime in the same range of size:

This is much less noisy and it seems that the real speedup is indeed closer to 167% than the 200% expected.

Explanation of the performance #

By comparing the code of the two version, we can see a few differences that could explain the lack of expected speedup.

(define (find-divisor n test-divisor)
  (cond ((> (square test-divisor) n)
         n)
        ((divides? test-divisor n)
         test-divisor)
        (else (find-divisor
               n
               (+ test-divisor 1)))))

(define (next n)
  (if (= n 2)
      3
      (+ 2 n)))

(define (find-divisor-improved n test-divisor)
  (cond ((> (square test-divisor) n)
         n)
        ((divides? test-divisor n)
         test-divisor)
        (else (find-divisor-improved
               n
               (next test-divisor)))))

The version for find-divisor-improved contains:

• one more function call to next, assuming that + is a basic operator.
• an if statement.
• the predicate (= n 2) to test.

To validate our hypothesys, let’s try a few experiments.

Experiment 1: inline the function next into find-divisor-improved to measure the performance impact of the function call #

(define (find-divisor-improved-inlined n test-divisor)
  (cond ((> (square test-divisor) n)
         n)
        ((divides? test-divisor n)
         test-divisor)
        (else (find-divisor-improved-inlined
               n
               (if (= test-divisor 2)
                   3
                   (+ 2 test-divisor))))))

On DrRacket:

We are now around 179% for speedup. Better, but not yet there.

Experiment 2: in the inlined next remove the = test to estimate its performance impact #

We need to cheat a little to do that, but since we are running this on prime number, we will just skip the test with 2 and start with 3.

(define (find-divisor-improved-inlined n test-divisor)
  (cond ((> (square test-divisor) n)
         n)
        ((divides? test-divisor n)
         test-divisor)
        (else (find-divisor-improved-inlined
               n
               (if #f
                   3
                   (+ 2 test-divisor))))))

On DrRacket:

We have almost 200% here! Buuuut, the problem by doing that is that we probably triggered the optimization of DrRacket JIT compiler for dead code optimization. It means that the if has probably been removed and our third hypothesis has been added here too.

Conclusion #

The improved algorithm did cut down the number of steps by 2, but the reason it didn’t speedup the computation by 200% was because we also added some new computation for each step:

• one more function call
• an if
• the predicate (= n 2)